автор перевода: Илья Михайлов	Предыдущая | Следующая | Оглавление

Camera.motionTimeOut

Доступность

Flash Player 6.

Синтаксис

active_cam.motionTimeOut:Number

Описание

Свойство только для чтения, количество миллисекунд, которое должно пройти между тем, как камера перестанет определять движение и моментом вызова Camera.onActivity(false). Значение по умолчанию равно 2000 (две секунды).

Для того, чтобы установить это значение, используйте Camera.setMotionLevel().

Пример

В следующем примере показано, как экзэмпляр компонента ProgressBar меняет цвет своей окантовки когда уровень активности опускается ниже уровня движения. Вы можете установить количество секунд для свойства motionTimeout, используя экзэмпляр компонента NumericStepper. Создайте новый экзэмпляр видео, выбрав New Video из меню настроек библиотеки (Library options menu). Добавьте экзэмпляр в сцену и дайте ему имя my_video. Добавьте экзэмпляр компонента Label в сцену и назовите его motionLevel_lbl. Добавьте экзэмпляр компонента NumericStepper в сцену и назовите его motionTimeOut_nstep. Затем добавьте экзэмпляр компонента ProgressBar в сцену и назовите его motion_pb. Скопируйте этот код в первый кадр таймлайна:

var motionLevel_lbl:mx.controls.Label;
var motion_pb:mx.controls.ProgressBar;
var motionTimeOut_nstep:mx.controls.NumericStepper;
var my_cam:Camera = Camera.get();
var my_video:Video;
my_video.attachVideo(my_cam);

this.onEnterFrame = function() {
  motionLevel_lbl.text = "activityLevel: "+my_cam.activityLevel;
};

motion_pb.indeterminate = true;
my_cam.onActivity = function(isActive:Boolean) {
  if (isActive) {
    motion_pb.setStyle("themeColor", "haloGreen");
    motion_pb.label = "Motion is above "+my_cam.motionLevel;
  } else {
    motion_pb.setStyle("themeColor", "haloOrange");
    motion_pb.label = "Motion is below "+my_cam.motionLevel;
  }
};
function changeMotionTimeOut() {
  my_cam.setMotionLevel(my_cam.motionLevel, motionTimeOut_nstep.value*1000);
}
motionTimeOut_nstep.addEventListener("change", changeMotionTimeOut);
motionTimeOut_nstep.value = my_cam.motionTimeOut/1000;

См. также

Camera.onActivity, Camera.setMotionLevel()

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление